How To Page Through a Recordset from ASP

MORE INFORMATION

This sample code demonstrates using Recordset Paging against the Adventure Works Access database.

The code Assumes the system DSN named AdvWorks is pointing to the Adventure Works Access 97 database.

<%@ EnableSessionState=False Language=VBScript %>
<%
set conn = Server.CreateObject("ADODB.Connection")
conn.Open "DSN=AdvWorks"

set rs = Server.CreateObject("ADODB.Recordset")
rs.CursorLocation = 3  ' adUseClient
rs.Open "Select * from Employees", conn
rs.PageSize = 2
intPageCount = rs.PageCount

Select Case Request("Action")
	case "<<"
		intpage = 1
	case "<"
		intpage = Request("intpage")-1
		if intpage < 1 then intpage = 1
	case ">"
		intpage = Request("intpage")+1
		if intpage > intPageCount then intpage = IntPageCount
	Case ">>"
		intpage = intPageCount
	case else
		intpage = 1
end select
%>
<HTML>
<HEAD>
<META NAME="GENERATOR" Content="Microsoft Visual Studio 6.0">
<TITLE>ASP & ADO Paging</TITLE>
</HEAD>
<BODY bgColor=White text=Black>

<%
rs.AbsolutePage = intPage 
For intRecord = 1 To rs.PageSize 
	Response.Write "Record	number: " & intRecord & " " 
	Response.Write rs.Fields("FirstName") & " " 
	Response.Write rs.Fields("LastName") & "<br>" 
	rs.MoveNext
If rs.EOF Then Exit For 

Next

rs.Close
set rs = Nothing
conn.Close
set conn = nothing
%>
<form name="MovePage" action="default.asp" method="post">
<input type="hidden" name="intpage" value="<%=intpage%>">
<input type="submit" name="action" value="<<">
<input type="submit" name="action" value="<">
<input type="submit" name="action" value=">">
<input type="submit" name="action" value=">>">
Page: <%=Intpage & " of " & intpagecount%>
</form>
</BODY>
</HTML>
				

When using Recordset Paging against SQL Server, you can use a server side cursor. However, you must use either a Static or a Keyset cursor type. Otherwise, no data will be returned. If you use a client side cursor, all cursor types will work, but only a static cursor is returned.

When using Recordset Paging against Microsoft Access, you must use a client side cursor. Any cursor type will work, but again only a static cursor is returned. A server side cursor will not return any data.

When using Recordset Paging against Oracle, you can use a server side cursor, but if you do, you must use a Static or Keyset cursor type. Otherwise, no data will be returned. If you use a client side cursor, all cursor types will work, but only a keyset cursor is returned.