FIX: AppendChunk Truncates Data Using OLE DB Provider for Oracle

MORE INFORMATION

Steps to Reproduce Behavior

1. 
   
2. Create a Standard EXE project in Visual Basic. Form1 is created by default.
3. Go to the Project/References menu and add a reference to Microsoft ActiveX Data Objects 2.0 Library.
4. Add three CommandButtons to the default form.
5. Add the following code in the code window of the form. You will have to modify the connection string to connect to your Oracle server:

         Option Explicit
         ' Connection String
         Const cnstr = "Provider=MSDAORA;Data Source=Ora8.world;User" & _
           " ID=demo;Password=demo;"
         Dim sqlstr As String
   
         Private Sub Command1_Click()
           Dim rs As New ADODB.Recordset
           Dim cn As New ADODB.Connection
           ' Don't throw an error in case the table does not exist
           On Error Resume Next
           sqlstr = "Create Table BlobTable (MYID Numeric Primary Key," & _
           " TXTFLD Long)"
           cn.Open cnstr
           ' Drop the table if it already exists
           cn.Execute "Drop table Blobtable"
           cn.Execute sqlstr
           cn.Close
           Set cn = Nothing
         End Sub
   
         Private Sub Command2_Click()
           Dim rs As New ADODB.Recordset
           Dim cn As New ADODB.Connection
           Dim i As Integer
           sqlstr = "Select MYID,TXTFLD from Blobtable where MYID=1"
           cn.CursorLocation = adUseClient
           cn.Open cnstr
           With rs
              .ActiveConnection = cn
              .CursorType = adOpenStatic
              .LockType = adLockOptimistic
              .Open sqlstr
           End With
           If rs.EOF Then
             rs.AddNew
             rs("MYID") = 1
             rs.Update
             rs.Requery
           End If
           For i = 1 To 1000
            'Store a 1 MB string; smaller strings may seem to work.
            rs.Fields("TXTFLD").AppendChunk String(1024, "x")
           Next i
           rs.Update
           rs.Close
           Set rs = Nothing
           cn.Close
           Set cn = Nothing
         End Sub
   
         Private Sub Command3_Click()
           Dim cn As New ADODB.Connection
           Dim rs As New ADODB.Recordset
           sqlstr = "Select MYID,TXTFLD from Blobtable where MYID=1"
           cn.CursorLocation = adUseClient
           cn.Open cnstr
           With rs
              .ActiveConnection = cn
              .CursorType = adOpenStatic
              .LockType = adLockOptimistic
              .Open sqlstr
           End With
           ' Print the actual size of the string stored in the database
           Debug.Print rs.Fields("TXTFLD").ActualSize
           rs.Close
           Set rs = Nothing
           cn.Close
           Set cn = Nothing
         End Sub
   
         Private Sub Form_Load()
          Command1.Caption = "Create Table"
          Command2.Caption = "Insert Data"
          Command3.Caption = "Retrieve Actual Size"
         End Sub
   					

6. Click the CommandButton with the caption "Create Table" to create the test table.
7. Click the CommandButton with the caption "Insert Data" to insert the data.
8. Click the CommandButton with the caption "Retrieve Actual Size" to retrieve the actual size of the text field. You will see a incorrect value printed in the Immediate window.