PRB: "Class Not Registered" Error Opening an XML Recordset

MORE INFORMATION

Steps to Reproduce Behavior

1. In Visual Basic, create a new Standard EXE project. Form1 is created by default.
2. From the Project menu, click References.
3. From the list of References, select the Microsoft ActiveX Data Objects Library.
4. Add two Command buttons to Form1. Command1 and Command2 are created by default.
5. Paste the following code into the Code window for Form1.
   
   Note You must change User ID <username> and Password <strong password> to the correct values before you run this code. Make sure that User ID has the appropriate permissions to perform this operation on the database.

   Private Sub Command1_Click()
   
      Dim cn As ADODB.Connection
      Dim rs As ADODB.Recordset
      
      Set cn = New ADODB.Connection
      Set rs = New ADODB.Recordset
   
      On Error Resume Next
      Kill "C:\Titles.XML"    
      On Error GoTo 0
   
      cn.Open "Provider=SQLOLEDB;Data Source=(local);" & _
              "Initial Catalog=Pubs;User ID=<user name>;Password=<strong password>;"
      
      rs.Open "select title_id, title from Titles", cn
      
     'Persist the Titles table to an XML file
      rs.Save "c:\Titles.xml", adPersistXML
      
      rs.Close
      Set rs = Nothing
      cn.Close
      Set cn = Nothing
      
   End Sub
   
   Private Sub Command2_Click()
   
       Dim rsXML As ADODB.Recordset
       Set rsXML = New ADODB.Recordset
    
       'Open the persisted recordset
       rsXML.Open "c:\Titles.xml"
       
       Do Until rsXML.EOF
          Debug.Print rsXML(0), rsXML(1)
          rsXML.MoveNext
       Loop
       
       rsXML.Close
       Set rsXML = Nothing
    
   End Sub
   
   Private Sub Form_Load()
     Command1.Caption = "&Persist"
     Command2.Caption = "&Retrieve"
   End Sub
   					

6. Modify the connection string to connect to your server, if necessary.
7. Select Run.
8. Click Persist to persist the Titles table as XML.
9. Click Retrieve to open the XML table.
   
   If the Microsoft XML Parser is not installed, an error occurs on rsXML.Open.