KB193664 - XL98: Macro to Append Text from One Text File to Another

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. In the following macro examples takes the data from one text file, Source, and append it to the data in the Destination text file.

To set up the example, use a text editor such as SimpleText to create the following text files.

The Destination file should contain the following information:

Name,Address,City,State,ZIP Code
John Smith,1 Main St.,Seattle,WA,12345
Jane Doe,2 East Rd,Charlotte,NC,52631
Tom Jones,3 West Cir.,Tuscon,AZ,36258

The Source file should contain the following information:

Bill Adams,6 Elm Ln.,Seattle,WA,85692
Sue Thompson,33 Maple Ct.,Las Colinas,TX,58692
Jerry Brown,32 Main Rd.,Tuscon,AZ,96524
Pamela Smith,88 Rain Rd.,Charlotte,NC,89526

The following macro demonstrates how you can use the Open, Line Input, and Print statements to read data from one text file and append it to another.

   Sub AppendFiles()

      Dim SourceNum As Integer
      Dim DestNum As Integer
      Dim Temp As String

      ' If an error occurs, close the files and end the macro.
      On Error GoTo ErrHandler

      ' Open the destination text file.
      DestNum = FreeFile()
      Open "Destination" For Append As DestNum

      ' Open the source text file.
      SourceNum = FreeFile()
      Open "Source" For Input As SourceNum

      ' Include the following line if the first line of the source
      ' file is a header row that you do now want to append to the
      ' destination file:
      ' Line Input #SourceNum, Temp

      ' Read each line of the source file and append it to the
      ' destination file.
      Do While Not EOF(SourceNum)
         Line Input #SourceNum, Temp
         Print #DestNum, Temp
      Loop

   CloseFiles:

      ' Close the destination file and the source file.
      Close #DestNum
      Close #SourceNum
      Exit Sub

   ErrHandler:
      MsgBox "Error # " & Err & ": " & Error(Err)
      Resume CloseFiles

   End Sub

After you run either macro, Destination should resemble the following:

Last Name, First Name, Address, City, State, Zip Code
John,Smith,1 Main St.,Seattle,WA,12345
Jane,Doe,2 East Rd,Charlotte,NC,52631
Tom,Jones,3 West Cir.,Tuscon,AZ,36258
Bill,Adams,6 Elm Ln.,Seattle,WA,85692
Sue,Thompson,33 Maple Ct.,Las Colinas,TX,58692
Jerry,Brown,32 Main Rd.,Tuscon,AZ,96524
Pamela,Smith,88 Rain Rd.,Charlotte,NC,89526

REFERENCES

XL98: Macro to Append Text from One Text File to Another

SUMMARY

MORE INFORMATION