HOWTO: Use GENHTML to Create HTML from a Visual FoxPro Report

MORE INFORMATION

1. Create a program file named Htmlrepo.prg containing the following code:

         USE HOME(2)+"DATA\CUSTOMER"
         CREATE REPO EXAMPLE FROM CUSTOMER
         CLOSE ALL
         DO (_GENHTML) WITH "EXAMPLE","EXAMPLE.FRX"
         CLOSE ALL
   
         * Set the class library to the _hyperlink class
         SET CLASSLIB TO home()+"ffc\_hyperlink.vcx"
         public ohyperlinkobject
         * Create a form with a hyperlink
         ohyperlinkobject=CREATEOBJECT('hyperform')
         ohyperlinkobject.SHOW
   
         DEFINE CLASS hyperform AS FORM
            TOP           = 0
            LEFT          = 0
            HEIGHT        = 75
            WIDTH         = 250
            DOCREATE      = .T.
            CAPTION       = "Display Example Report"
            NAME          = "Form1"
            SHOWTIPS      = .T.
   
            ADD OBJECT _hyperlinklabel1 AS _hyperlinklabel WITH ;
               LEFT       = 25, ;
               TOP        = 10, ;
               HEIGHT     = 25, ;
               VISIBLE    = .T., ;
               FONTNAME   = "Times New Roman", ;
               FONTSIZE   = 14, ;
               FONTITALIC = .T., ;
               AUTOSIZE   = .T., ;
               ctarget    = sys(5)+sys(2003)+"\EXAMPLE.HTM", ;
               CAPTION    = "Example Report", ;
               lnewwindow = .T., ;
               NAME       = "_HYPERLINKLABEL1"
   
         ENDDEFINE
         * End Code
   						

2. When the Form captioned "Display Example Table" displays, click the hyperlink label to display the HTML generated by the GENHTML program.