INFO: Print Out File Properties Using the FileSystemObject

MORE INFORMATION

This article assumes you are familiar with using objects, collections, and object models in Visual Basic. The FileSystemObject allows you to perform a number of tasks on the file system of a computer. This object is available to your project by making a reference to the Microsoft Script Runtime file scrrun.dll. This file ships with Windows 98 and the following products:

After making a reference to the Script Runtime file, you create an instance of the FileSystemObject using the CreateObject method. The FileSystemObject can create a text file with the CreateTextFile method. You write to the text file using the Write, the WriteBlankLines, or the WriteLine functions.

To get the properties of all files in a specified folder, open the folder using the GetFolder method. You can then loop through each member of the Files collection and get the properties of each file.

The next section shows you how to create a sample project that demonstrates using the FileSystemObject to get the properties of all files in a specified directory. These properties are then printed to a text file.

Steps to Create Sample Project

1. Start a new Standard EXE project in Visual Basic. Form1 is created by default.
2. Add a reference to the Microsoft Script Runtime by completing the following steps:
   1. From the Project menu, click References to display the References dialog box.
   2. Click Browse to open the Add Reference dialog box.
   3. Select the file scrrun.dll and click OK to close the Add Reference dialog box. This file is installed in your system directory. Microsoft Scripting Runtime appears with a check in the Available Referenced list box of the References dialog box.
   4. Click OK to close the References dialog box.
3. Add the following controls to Form1:
   • CommandButton
   • DriveListBox
   • DirListBox
   • Label
4. Copy the following code to the Code window of Form1:

   Option Explicit
         
   Private Sub Form_Load()
      Label1.AutoSize = True
      Label1.Caption = Dir1.Path
      Dir1.Path = Drive1.Drive
      Command1.Caption = "Create File List"
   End Sub
   
   Private Sub Dir1_Change()
      Label1.Caption = Dir1.Path
   End Sub
   
   Private Sub Drive1_Change()
      Dir1.Path = Drive1.Drive
   End Sub
   
   Private Sub Command1_Click()
      Dim fso As FileSystemObject
      Dim f As Folder
      Dim fc As Files
      Dim fl As File
      Dim ts As TextStream
      Dim sFileName As String
      Dim sVersion As String
   
      Set fso = CreateObject("Scripting.FileSystemObject")
      sFileName = InputBox("Enter File Name", _
                           "Enter Path and File Name")
   
      If sFileName = "" Then
         Exit Sub
      Else
         Set ts = fso.CreateTextFile(sFileName, True, False)
         Set f = fso.GetFolder(Dir1.Path)
         Set fc = f.Files
         With ts
            .WriteLine ("Files in " & Dir1.Path)
            .WriteBlankLines (1)
   
            For Each fl In fc
               .WriteLine ("Filename: " & fl.Name)
               .WriteLine (vbTab & "File Type: " & fl.Type)
               
               ' Get Version Information
               sVersion = fso.GetFileVersion(fl.Path)
               If sVersion <> "" Then
                  .WriteLine (vbTab & "Version: " & fso.GetFileVersion(fl.Path))
               Else
                  .WriteLine (vbTab & "No Version Information")
               End If
               
               .WriteLine (vbTab & "Created: " & fl.DateCreated)
               .WriteLine (vbTab & "Last Modified: " & _
                           fl.DateLastModified)
               .WriteLine (vbTab & "Last Accessed: " & _
                           fl.DateLastAccessed)
               .WriteLine (vbTab & "Path: " & fl.Path)
               .WriteLine (vbTab & "Short Name: " & fl.ShortName)
               .WriteLine (vbTab & "Size: " & fl.Size & " bytes")
               .WriteBlankLines (1)
            Next
         End With
         MsgBox (sFileName & " created.")
      End If
      
      'Destroy All Objects
      Set fc = Nothing
      Set f = Nothing
      Set ts = Nothing
      Set fso = Nothing
   End Sub
   					

5. On the Run menu, click Start or press the F5 key to start the program.
   
   1. Select a drive and a folder. The path appears in the Label control.
   2. Click the Create a file list CommandButton. An input dialog box appears.
   3. Type the path and file name of the text file that will contain the file properties. Click OK to close the input box.
   A message box appears when the text file is created. Open the text file to view the results.