ACC97: How to Programmatically Display a Help File

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

Method 1

You can use the Shell command to display a Help file. To do so, follow these steps:

1. Create a new form.
2. Add a command button to the form.
3. In the Click event of the command button, type the following code:

   Shell "winhlp32.exe c:\win95\system\msadtctl.hlp"
   					

NOTE: You should verify the name and path to the Help file you use.

Method 2

When you run the code in Method 1 for the first time, the form will most likely open on the Contents Tab. However, if you then switch to the Index tab, close the Help file, and run the code again, the Index tab will be displayed. Whichever tab was last active is displayed each time you run the code.

If you have the Microsoft Access Developer's Toolkit 7.0 or the Microsoft Office 97 Developer Edition, you can avoid this problem by using the Common Dialog control. To do so, follow these steps:

1. On a new form, click ActiveX controls on the Insert menu.
2. In the Insert ActiveX Control dialog box, select the Common Dialogs Control, and click OK. Microsoft Access should give it the name ActiveXCtl0.
3. Add a command button to the form.
4. Type the following code for the Click event of the command button:

   With ActiveXCtl0   'Refers to the common dialog control
     .HelpFile = "c:\windows\system\calc.hlp"
     .HelpCommand = 15
     .ShowHelp
   End With
   					

5. View the form in Form view and click the button. The Contents tab appears.
6. Switch to the Index tab, and then close the Help file.
7. Click the button again. Note that the Contents tab re-appears. The Help file does not open with the Index tab active.

NOTE: If you change the 15 setting to 11 for the .HelpCommand line in the code in step 4, you should get the same results as when using the Shell command to open the Help file.

Method 3

A more powerful way to display a Help file is to use Microsoft Windows API calls. These require some functions that you must first enter into a module. To do so, in a new module, type the following code. (Descriptions of how to use each of these API functions appear at the end of this article.)

NOTE: You may have some Microsoft Windows API functions defined in an existing Microsoft Access library; therefore, your declarations may be duplicates. If you receive a duplicate procedure name error message, remove or comment out the declarations statement in your code.

 Option Compare Database
   Option Explicit

   Public Const HELP_CONTEXT = &H1        ' Display topic by Help
                                          ' context ID.

   Public Const HELP_QUIT = &H2           ' Terminate Help.

   Public Const HELP_INDEX = &H3          ' Display Help index.

   Public Const HELP_CONTEXTPOPUP = &H8&  ' Display Help context as a
                                          ' pop-up window.

   Public Const HELP_FINDER = &HB&        ' If found, Display
                                          ' container file.

   Public Const HELP_KEY = &H101          ' Display topic for
                                          ' keyword.

   ' Declare the WinHelp function.
   Declare Sub WinHelp Lib "user32" Alias _
   "WinHelpA" (ByVal Hwnd As Long, ByVal lpHelpFile As String, _
   ByVal wCommand As Long, ByVal dwData As Any)

   Function OpenHelpContainer(ByVal strHelpFileName As String)
   ' Opens the Help container.

       WinHelp Application.hWndAccessApp, _
       ByVal strHelpFileName, HELP_FINDER, ByVal vbNullString
   End Function

   Function OpenHelpIndex(ByVal strHelpFileName As String)
   ' Opens the Help index.

    WinHelp Application.hWndAccessApp, ByVal strHelpFileName, _
    HELP_KEY, ByVal ""
   End Function

   Function OpenHelpIndexWithSearchKey(ByVal strHelpFileName _
   As String, ByVal strSearchKey As String)
       ' Opens the Help index and searches for keyword SKey.

       WinHelp Application.hWndAccessApp, ByVal _
       strHelpFileName, HELP_KEY, ByVal strSearchKey

   End Function

   Function OpenHelpWithContextID(ByVal strHelpFileName As _
   String, lngContextID As Long)

        ' Opens the Help file to ContextID.

        WinHelp Application.hWndAccessApp, ByVal strHelpFileName, _
        HELP_CONTEXT, ByVal lngContextID

   End Function

   Function OpenHelpWithContextIDPopup(ByVal strHelpFileName As String, _
   lngContextID As Long)

       ' Opens the Help file to ContextID as a pop-up window.

       WinHelp Application.hWndAccessApp, ByVal strHelpFileName, _
       HELP_CONTEXTPOPUP, ByVal lngContextID

   End Function

   Function CloseHelpContainer(ByVal strHelpFileName As String)

       ' Closes the specified Help file.

       WinHelp Application.hWndAccessApp, _
       ByVal strHelpFileName, HELP_QUIT, ByVal vbNullString

   End Function
				

The above code provides some useful functions for displaying Help files. The list below describes the purpose of each.

NOTE: The follow examples use the Help file "Calc.hlp" because it is usually in the System folder and does not require a complete path.

1. OpenHelpContainer() You can use the OpenHelpContainer function simply to open a Help file. To test this function, type the following in the Debug window:

   ?OpenHelpContainer("Calc.hlp")
   						

   This opens the Help file for the Microsoft Windows Calculator.
2. OpenHelpIndex() Opens the Help file with the Index tab activated. To test this function, type the following in the Debug window:

   ?OpenHelpIndex("Calc.hlp")
   						

   This opens the Help file for the Microsoft Windows Calculator with the Index tab displayed.
3. OpenHelpIndexWithSearchKey() Opens the specified Help index and searches for a keyword. To test this function, type the following in the Debug window:

   ?OpenHelpIndexWithSearchKey("calc.hlp","simple calculations")
   						

   Note that the "Simple Calculations" topic ID is displayed.
4. OpenHelpWithContextID() Opens the Help file to a specified ContextID. To test this function, type the following in the Debug window:

   ?OpenHelpWithContextID("calc.hlp",90)
   						

   Note that it opens Help for the division button.
5. OpenHelpWithContextIDPopup() Opens the Help file to a specified ContextID as a pop-up window. To test this function, type the following in the Debug window:

   ?OpenHelpWithContextIDPopup("Calc.hlp",90)
   						

   Note that it opens Help for the division button in a pop-up window.
6. CloseHelpContainer() Closes the Help file. To test this function, type the following in the Debug window:

   ?CloseHelpContainer("Calc.hlp")
   						

   This should close the Microsoft Windows Calculator Help file if it is open.