WD98: VB Macro Examples to Insert Text into a Document

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

Using the Selection Object and the TypeText Method

Inserts the specified text. If the ReplaceSelection Property is True, the selection is replaced by the specified text. If ReplaceSelection Property is False, the specified text is inserted before the selection.

For more information about the ReplaceSelection Property, from the Visual Basic Editor, click the Office Assistant, type ReplaceSelection Property, click Search, and then click to view "ReplaceSelection Property."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base:

   Sub TypeTextMethod()
     Dim MyText As String
     MyText = "<Replace this with your text>"
     Selection.TypeText (MyText)
   End Sub
				

Using the Range object

The following example replaces the entire contents of a document with the word "Replaced" regardless of the current position of the insertion point.

   Sub RangeProperty()
     ' Range Example:
     ActiveDocument.Range.Text = "Replaced"
   End Sub
				

Using Range or Selection Object with the InsertAfter/InsertBefore Method

InsertAfter Method example:

Inserts the specified text at the end of a range or selection.

Sub InsertAfterMethod()
     Dim MyText As String
     Dim MyRange As Object
     Set MyRange = ActiveDocument.Range
     MyText = "<Replace this with your text>"

     ' Selection Example:
     Selection.InsertAfter (MyText)

     ' Range Example:
     ' (Inserts text at the current position of the insertion point.)
     MyRange.Collapse
     MyRange.InsertAfter (MyText)
   End Sub
				

InsertBefore Method example:

Inserts the specified text at the beginning of a range or selection. After this method is applied, the range or selection expands to include the new text.

   Sub InsertBeforeMethod()
      Dim MyText As String
      Dim MyRange As Object
      Set MyRange = ActiveDocument.Range
      MyText = "<Replace this with your text>"

      ' Selection Example:
      Selection.InsertBefore (MyText)

      ' Range Example: Inserts text at the beginning
      ' of the active document.
      MyRange.InsertBefore (MyText)
   End Sub
				

Inserting a Comment into a Document Using the Range or Selection Object

Inserts a comment at the current position of the insertion point.

   Sub CommentsCollectionObject()
      Dim MyText As String
      Dim MyRange As Object
      Set MyRange = ActiveDocument.Range
      MyText = "<Replace this with your text>"

     ' Selection Example:
     Selection.Comments.Add Range:=Selection.Range, Text:=MyText

     ' Range Example:
     MyRange.Comments.Add Range:=Selection.Range, Text:=MyText
   End Sub
				

Inserting a Field into a Document Using the Range or Selection Object

Inserts a field at the current position of the insertion point.

   Sub FieldsCollectionObject()
      Dim MyText As String
      Dim MyRange As Object
      Set MyRange = Selection.Range
      MyText = "<Replace this with your text>"

      ' Selection Example:
      Selection.Fields.Add Range:=Selection.Range, _
         Type:=wdFieldQuote, Text:=MyText

      ' Range Example:
       Range.Fields.Add Range:=Selection.Range, _
         Type:=wdFieldQuote, Text:=MyText
   End Sub
				

This example inserts a formula field. The result is formatted with a dollar sign.

   Sub InsertFormulaMethod()
      Selection.InsertFormula Formula:="=100,000.0-45,000.0", _
         NumberFormat:="$#,##0.0"
   End Sub
				

Replicating the Text, Including the Format, of a Text Range

This property returns a Range object with the character formatting and text from the specified range or selection. Paragraph formatting is included in the Range object if there is a paragraph mark in the range or selection. When you set this property, the text in the range is replaced with formatted text. If you do not want to replace the existing text, use the Collapse method before using this property.

   Sub FormattedTextProperty()
      ' This example copies the first paragraph in the document, including
      ' its formatting, and inserts the formatted text at the insertion
      ' point.
      Selection.Collapse Direction:=wdCollapseStart
      Selection.FormattedText = ActiveDocument.Paragraphs(1).Range
   End Sub
				

Placing Text into a Header or Footer

NOTE: The HeaderFooter property requires that the selection be located within a header or footer or an error will occur.

   Sub HeaderFooterProperty()
      Dim MyText As String
      MyText = "<Replace this with your text>"
      ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageHeader
      Selection.HeaderFooter.Range.Text = "MyText"
      ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
   End Sub
				

The following example changes the text of both the primary header and the primary footer for the first section of the active document.

   Sub HeaderFooterObject()
     Dim MyText As String
     MyHeaderText = "<Replace this with your text>"
     MyFooterText = "<Replace this with your text>"
     With ActiveDocument.Sections(1)
       .Headers(wdHeaderFooterPrimary).Range.Text = MyHeaderText
       .Footers(wdHeaderFooterPrimary).Range.Text = MyFooterText
     End With
   End Sub
				

Using the Range or Selection Object to Insert a Date Using the Time Field

This example inserts a Time field for the current date. A possible result might be "November 18, 1996."

   Sub InsertDateTimeMethod()
      Dim MyRange As Object
      Set MyRange = Selection.Range

      ' Selection Example:
      Selection.InsertDateTime DateTimeFormat:="MMMM dd, yyyy", _
      InsertAsField:=True

      ' Range Example:
      MyRange.InsertDateTime DateTimeFormat:="MMM dd, yyyy", _
      InsertAsField:=True
   End Sub
				

Using the Range or Selection Object to Insert a New Paragraph

This example inserts a new paragraph below the current position of the insertion point.

   Sub InsertParagraphMethod()
      Dim MyRange As Object
      Set MyRange = ActiveDocument.Range

      ' Selection Example:
      Selection.InsertParagraph

      ' Range Example:
      MyRange.Collapse Direction:=wdCollapseStart
      MyRange.InsertParagraph
   End Sub
				

Using the Range or Selection Object to Insert a Symbol

This example inserts a double-headed arrow at the insertion point.

   Sub InsertSymbolMethod()
      Dim MyRange As Object
      Set MyRange = ActiveDocument.Range

      ' Selection Example:
      Selection.InsertSymbol CharacterNumber:=171, _
         Font:="Symbol", Unicode:=False

      ' Range Example:
      MyRange.Collapse Direction:=wdCollapseStart
      MyRange.InsertSymbol CharacterNumber:=171, _
         Font:="Symbol", Unicode:=False
   End Sub
				

Using the Range or Selection Object to Paste from the Clipboard

This example inserts text placed on the clipboard at the current position of the insertion point.

   Sub PasteMethod()
      Dim MyRange As Object
      Set MyRange = Selection.Range

      ' Selection Example:
      Selection.Paste

      ' Range Example:
      MyRange.Collapse Direction:=wdCollapseStart
      MyRange.Paste
   End Sub
				

For more information about using the Range Object, from the Visual Basic Editor, click the Office Assistant, type Range Object, click Search, and then click to view "Range Object."

For more information about using the Selection Object, from the Visual Basic Editor, click the Office Assistant, type Selection Object, click Search, and then click to view "Selection Object."

NOTE: If the Assistant is hidden, click the Office Assistant button on the Standard toolbar. If the Assistant is not able to answer your query, please see the following article in the Microsoft Knowledge Base: For additional information, please see the following article in the Microsoft Knowledge Base: