How To Programmatically Register and Unregister .OCX Files

MORE INFORMATION

Step-by-Step Example

1. Create a new Standard Exe project in Visual Basic.
2. Add a Module (Module1) to the project.
3. Add the following code to the General Declarations section of Module1:

         Public Declare Function RegComCtl32 Lib "ComCtl32.OCX" _
            Alias "DllRegisterServer" () As Long
   
         Public Declare Function UnRegComCtl32 Lib "ComCtl32.OCX" _
            Alias "DllUnregisterServer" () As Long
   
         Public Const S_OK = &H0
   
         Sub RegisterComCtl32()
            On Error GoTo Err_Registration_Failed
            If RegComCtl32 = S_OK Then
               MsgBox "Registered Successfully"
            Else
               MsgBox "Not Registered"
            End If
         Exit Sub
         Err_Registration_Failed:
            MsgBox "Error: " & Err.Number & " " & Err.Description
         End Sub
   
         Sub UnRegisterComCtl32()
            On Error GoTo Err_Unregistration_Failed
            If UnRegComCtl32 = S_OK Then
               MsgBox "Unregistered Successfully"
            Else
               MsgBox "Not Unregistered"
            End If
         Exit Sub
         Err_Unregistration_Failed:
            MsgBox "Error: " & Err.Number & " " & Err.Description
         End Sub
   
   					

4. View the Immediate Window (CTRL+G) and type:
   

   UnRegisterComCtl32

   Press the ENTER key to unregister ComCtl32.OCX, and then type:
   

   RegisterComCtl32

   and press the ENTER key to register the control.

• "RegComCtl32" and "UnRegComCtl32" are user-defined names and may be changed to suit your needs.
• The Step-by-Step Example above assumes that ComCtl32.OCX is located in the Windows\System folder of the local hard drive. If it is not located there, you must specify the complete path to the .OCX file in the Declare statement.
• "DllRegisterServer" and "DllUnregisterServer" are case-sensitive. It is important that the correct case be used when declaring these functions.