How To Undo Updates for a Single Row with CancelBatch

MORE INFORMATION

Step-by-step example

1. Start Visual Basic and create a standard EXE. Form1 is added by default.
2. Add a reference to "Microsoft Remote Data Object 2.0" in Project/ References.
3. Add two CommandButtons, called Command1 and Command2, to Form1.
4. Set the Caption property of Command1 to "Edit and Undo" and the Caption property of Command2 to "Delete and Undo".
5. Copy and paste the following code to the General Declarations section of Form1.
   
   Note You must change UID <username> and PWD <strong password> to the correct values before you run this code. Make sure that UID has the appropriate permissions to perform this operation on the database.

        Dim cn As New rdoConnection
        Dim rs As rdoResultset
   
        Private Sub Form_Load()
   
            cn.CursorDriver = rdUseClientBatch
            cn.Connect = "dsn=my_pubs_server;uid=<username>;pwd=<strong password>"
            cn.EstablishConnection rdDriverNoPrompt, False
            Set rs = cn.OpenResultset("select * from authors", rdOpenStatic, _
                                      rdConcurBatch)
   
        End Sub
   
        Private Sub Command1_Click()
   
            rs.MoveFirst
            rs.Edit
            rs(1) = "New Value"
            rs.Update
   
            MsgBox "Status before CancelBatch: " & rs.Status
            rs.CancelBatch SingleRow:=True
            MsgBox "Status after CancelBatch: " & rs.Status
   
        End Sub
   
        Private Sub Command2_Click()
   
            rs.MoveFirst
            rs.Delete
            rs.MoveNext
   
            On Error Resume Next
            rs.AbsolutePosition = 1
            MsgBox "Status before CancelBatch: " & rs.Status
            rs.CancelBatch SingleRow:=True
            MsgBox "Status after CancelBatch: " & rs.Status
   
        End Sub
   
        Private Sub Form_Unload(Cancel As Integer)
   
            rs.Close
            cn.Close
   
            Set rs = Nothing
            Set cn = Nothing
   
        End Sub
   						

6. Finally, press the F5 key to run.