How To List Stored Procedures in a SQL Server Database

MORE INFORMATION

1. Start a new Project in Visual Basic. Form1 is created by default.
2. Add a Command button (Command1) and a List Box (List1) to Form1.
3. Add the following code to Form1.
   
   Note You must change UID =<username> and PWD =<strong password> to the correct values before you run this code. Make sure that UID has the appropriate permissions to perform this operation on the database.

         Private Sub Command1_Click()
           Dim cn As rdoConnection
           Dim ps As rdoPreparedStatement
           Dim rs As rdoResultset
           Dim strConnect As String
           Dim strSQL As String
           'open a connection to the pubs database using DSNless connections
           'change the Server argument to match your SQL Server
           strConnect = "Driver={SQL Server}; Server=myserver; " & _
                        "Database=pubs; Uid=<username>; Pwd=<strong password>"
           Set cn = rdoEnvironments(0).OpenConnection(dsName:="", _
                    Prompt:=rdDriverNoPrompt, _
                    ReadOnly:=False, _
                    Connect:=strConnect)
   
           strSQL = "Select so.name,sc.name,st.name,sc.length " & _
              "FROM syscolumns sc,master..systypes st,sysobjects so " & _
              "WHERE sc.id in (select id from sysobjects where type ='P')" & _
              " AND so.type ='P' " & _
              "AND sc.id = so.id " & _
              "AND sc.type = st.type " & _
              "AND sc.type <> 39"
           'create a prep stmt for the stored proc call
           Set ps = cn.CreatePreparedStatement("MyPs", strSQL)
   
           Set rs = ps.OpenResultset(rdOpenStatic)
   
           'add the first resultset to a list box
           list1.AddItem "SP Name,Param Name,Data Type,Length"
           While Not rs.EOF
              list1.AddItem rs(0) & " , " & rs(1) & " , " & rs(2) & " , " & _
                            rs(3)
              rs.MoveNext
           Wend
           'Close the resultset and the connection and set both to nothing
           rs.Close
           Set rs = Nothing
           cn.Close
           Set cn = Nothing
         End Sub
   
         Private Sub Form_Load()
           Command1.Caption = "List all Stored Procedures"
         End Sub
   
   						

4. Press the F5 key to run the program. Click the button labeled "List all Stored Procedures." A List of all stored procedures and their parameters should now appear.