The do loop executes statement first and then evaluates condition_exp. If expression is true (not the value 0), the statement continues to be executed until expression becomes false (0) or a break statement is reached.

Example:

    [label:] do statement while ( condition_exp );
      

The C-style for loop is free-form. The expressions before the first semicolon of the for loop are executed before entering the loop. The condition_exp expression is checked before entering the for loop also. If condition_exp is true (not the value 0), the statement is executed. The statement continues to be executed until condition_exp becomes false (0) or a break statement is reached. When the bottom of the for loop is reached, but before condition_exp is checked again, the expressions after the second semicolon are executed.

The syntax of for is:

    [label:] for (b4e1 ,b4e2 ... .b4e3]; [condition_exp] ; {cont_e1,cont_e2 ... ,cont_e3]) statement
      

Examples:

// The following loops are equivalent.
loop1:  
   for ( i=1;i<10;++i ) {
      messageNwait("i="i);
   }
loop2:
   i=1;
   for ( ;i<10; ) {
      messageNwait("i="i);
      ++i;
   }
loop3:
   for ( i=1;i<10;++i ) messageNwait("i="i);
loop4:
   i=1;
   while ( i <10 ) {
      messageNwait("i="i++);
   }
loop5:
   i=1;
   do {
      messageNwait("i="i);
   } while ( i<10 );

The foreach statement works with arrays, hash tables, strings (same as Bourne shell), structs (iterates over the fields of the struct), and classes (if instance of sc.lang.llterable, otherwise like structs). The syntax of foreach is:

    foreach ( [ k => ] v in a ) {
    statements;
    }
      

Example:

void printStats(int (&statistics):[])  
{
   foreach (auto name => auto count in statistics) {
      say("testForeach: "name"="count);
   }
   int i,j=0;
   foreach (i in range(10, 20, 2)) {
      say("printStats: sequence["j++"]="i);
   }
}

There is an optional key which is useful for hash tables. The value can be omitted (key=> . in ht):

   foreach( key => value in ht ) {
      statements;
   }

Both value and index can be auto-declared using the auto keyword. If value is auto-declared, its type will be inferred from the type of the collection. The implementation uses _nextel().

The generic loop statement is similar to that found in the Ada and D languages. The following statements are equivalent:

for(;;) { ... } 
loop { ... }

Example:

status := search(":","@");  
loop {
   if ( status ) break;
   get_line(line);
   messageNwait("found match line="line);
   status = repeat_search();
}

Another example:

defmain()
{
   i:=0;
   j:=0;
   loop {
      say("test, i="i);
      i++;
      if (i>1000) {
         break;
      }
      inner: loop {
         say("defmain: j="j);
         if (j++ > 750) break inner;
      }
      say("defmain: H1");
      if (i < 500) {
         continue;
      }
      say("defmain: H2");
   }
}

The while loop evaluates condition_exp first and then executes statement if condition_exp is true (not the value 0). The statement will continue to be executed until condition_exp becomes false (0) or a break statement is reached.

Example:

    [label:] while (condition_exp) statement
      

Loops are exited with the break primitive. The break primitive supports an optional label argument (like Java™). If specified, the label must match the label of one of the loops that you are currently using.

The continue primitive can be used to skip to the top of a loop. Using continue on a for loop causes the expressions after the second semicolon to be executed before condition_exp is checked. When continue is used on a do statement, the condition_exp is not checked and execution resumes at the top of the loop.

Loops can also be exited with the continue primitive. The continue primitive supports an optional label argument (like Java). If specified, the label must match the label of one of the loops that you are currently using.

Example:

outerloop:
   for ( i=1;i<3;++i ) {
      for ( j=1;;++j ) {
         if ( j==2 ) continue outerloop;  // Exit inner loop.
         if ( j==3 ) break outerloop;     // Exit both loops.
         messageNwait("i="i);
      }
   }